?=======================================================================
?
? Analysis of Panel Probit data, panelprobit.lpj
?
?=======================================================================
?
?  1.  Cluster Covariance matrix
?
Sample ; All $
Namelist ; X = One,IMUM,FDIUM,SP,LogSALES $
Probit ; Lhs = IP ; Rhs = X ; mar $
Matrix ; Var0 = Varb $  (Uncorrected covariance matrix)
Probit ; Lhs = IP ; Rhs = X ; Cluster = 5 $
Matrix ; VarPanel = Varb $ (Corrected covariance matrix)
? PCTDIFF is the percentage difference between the estimated standard errors $
Matrix ; SD0 = Diag(Var0)  ; Diff = Vecd(VarPanel) - Vecd(Var0) 
       ; List ; PctDiff = 100*<SD0>*Diff$
?
?  2.  Robust Covariance matrix only corrects for heteroscedasticity
?
Probit ; Lhs = IP ; Rhs = X $
Matrix ; Var0 = Varb $  (Uncorrected covariance matrix)
Probit  ; Lhs = IP  ; Rhs = X ;  RobustVC $
Matrix  ; VarHet = Varb $
Matrix ; SD0 = Diag(Var0)  ; Diff = Vecd(VarHet) - Vecd(Var0) 
       ; List ; PctDiff = 100*<SD0>*Diff$ - Init(5,1,100) $

?
?  3.  Marginal Effects for a quadratic
Create   ; LogS2  = LogSales^2 $
Namelist ; X2     = One,IMUM,FDIUM,SP,LogSALES,LogS2 $
Probit   ; Lhs    = IP ; Rhs = X2 ; Mar $
Wald     ; Start  = b ; Var = Varb
         ; Labels = beta0,beta1,beta2,beta3,a0,a1
         ; Fn1    = n01(beta0'X2)*(a0+2*a1*Logsales) 
         ; Fn2    = n01(beta0'X2)*beta2 
         ; Average $
?       Easy way
Namelist ; X = One,IMUM,FDIUM,SP $
probit   ; Lhs = ip ; rhs = x,logsales,logsales^2 $
partial  ; effects: logsales / fdium $
Partial  ; effects: logsales & fdium = .05(.05)1 ; plot(ci) $


?
?  4.  Heteroscedasticity in a logit model
?
Namelist ; X = one,imum,fdium,sp,logsales $
Logit   ; Lhs = IP ; Rhs = X ; Het 
        ; Hfn = RAWMTL; Marginal Effects $
Partial ; Function = lgp((b1+b2*IMUM+b3*FDIUM+b4*SP+b5*LogSALES)/exp(c1*rawmtl))
        ; Labels   = b1,b2,b3,b4,b5,c1
        ; parameters = b
        ; covariance = varb
        ; effects: rawmtl / logsales$
Logit   ; Lhs = IP ; Rhs = X ; Het 
        ; Hfn = LogSales; Marginal Effects $
Partial ; Function = lgp((b1+b2*IMUM+b3*FDIUM+b4*SP+b5*LogSALES)/exp(c1*LogSales))
        ; Labels   = b1,b2,b3,b4,b5,c1
        ; parameters = b
        ; covariance = varb
        ; effects: logsales ; means$

?
?  5. Nonparametric and Semiparametric Estimators
?
Namelist ; X0 = IMUM,FDIUM,SP,LogSALES $
Namelist ; X = One,X0 $
Reject ; T > 1 $ (Use only first year of data)

?  Fully Parametric

Probit ; Lhs = IP ; Rhs = X $ 

?  Semiparametric:  Maximum Score

Reject ; T > 1 $
Mscore ; Lhs = IP ; Rhs = X $
Semiparametric ; LHS = IP ; Rhs = X0 $ (Klein and Spady.)

?  Nonparametric, Kernel density regression estimator
?  Note, the nonparametric estimator can only have one RHS variable

NPREG ; LHS = IP ; Rhs = LogSales $
?
?  6.  Plot of Probabilities
?
Reject     ; New ; T > 1 $
Probit     ; Lhs = IP ; Rhs = one,IMUM,FDIUM,SP,logsales $
Calc       ; Low = .5*Min(LogSales) ; High = 1.5*Max(LogSales)  
           ; inc = .05*(high-low) $$
partials ; simulate ; effects: logsales & logsales = Low(inc)high
;plot(ci)
;title=Simulation of Innovation Probabilities vs. Log Sales$

?
?  7.  Testing for Structural Change
?
Sample ; All $
Namelist ; X = One,IMUM,FDIUM,SP,LogSALES $
Probit ; Lhs = IP ; Rhs = X ; quietly $  (We suppress the model results)
Calc ; Logl0 = Logl ; Logl1 = 0 ; i = 0 $
Procedure
Include ; New ; T = i $
Probit ; Lhs = IP ; Rhs = X $
Calc ; Logl1 = Logl1 + Logl $
EndProc $
Execute ; i = 1,5 ; Silent $ (This suppresses the individual year results.)
Calc ; List ; Chisq = 2*(Logl1 - Logl0) ; Df = 4*Col(X) ; Ctb(.95,df) $
?
?  9.  Hypothesis Tests
?
Reject   ; New ; T < 5 $
Namelist ; X = One,IMUM,FDIUM,LogSales $
Namelist ; Sectors = RawMtl,InvGood$
Probit   ; Lhs = IP ; Rhs = X $
Calc     ; Logl0 = LogL $
Probit   ; Lhs = IP ; Rhs = X ; Het ; Hfn = Sectors
         ; Start = b,0,0 ; Maxit = 0 $
Probit   ; Lhs = IP ; Rhs = X,Sectors ; Parameters ; test: sectors = 0$
Calc     ; KX = Col(X) ; K1 = KX + 1 ; Kc = Col(Sectors); K = KX + KC$
Matrix   ; c = B(K1:K) ; vc = Varb(K1:K , K1:K) $
Matrix   ; List ; Wald = c'<vc>c  $
Calc     ; List ; Ctb(.95,2) $
Wald     ; start = b ; Var = Varb ; labels=KX_d,Kc_c  
              ; fn1 = c1 - 0 ; Fn2 = c2 - 0 $
?
?  10.  Binary Choice Model Simulation
?  
Probit ; Lhs = IP ; Rhs=one,logsales,imum,fdium $
BinaryChoice  ; Lhs = IP ; Rhs = one,logsales,imum,fdium 
; model=probit  ; start=b ; scenario: fdium * = 1.5 ;plot:fdium $