import;file=h:\gasoline.csv$
create ; lg=log(g);lpg=log(pg);ly=log(pcincome)$
create ; ppnc=log(pnc);lpuc=log(puc) ; lppt=log(ppt) $
? Part 1.
regr;lhs=lg;rhs=one,lpg,ly,ly*ly; covariance$
calc ; v33=varb(3,3) ; v44=varb(4,4) ; v34=varb(3,4) $
calc ; lybar=xbr(ly)$
calc ; list ; sdv = sqr(v33 + 2*(2*lybar)*v34 + (2*lybar)^2 * v44)$
calc ; list ; pe = b(3) + 2*lybar*b(4) $
calc ; list ; lowerci = pe-1.96*sdv ; upperci = pe+1.96*sdv$
partials ; effects: ly ; means $
? Part 2.
? given b2, c(b2)=exp(b2)-1.  The derivative is exp(b2), so the variance
? is [exp(b2)]^2 times the variance.
calc ; list ; b2 = b(2) ; c = exp(b2)-1 $
calc ; list ; var = (exp(b2))^2 * varb(2,2) $
calc ; list ; sd = sqr(var) $
wald ; fn1 = exp(b_lpg)-1$
? Now, Krinsky and Robb
Sample ; 1 - 1000 $
Calc   ; sd2 = sqr(varb(2,2))$
create ; b2i = Rnn(b2,sd2) $
create  ; ci = exp(b2i)-1 $
dstat;rhs=ci $
? Part 3
sample;1-52$
regr;lhs=lg;rhs=one,lpg,ly,ly*ly$
sample;1$
fplot;fcn=-18.6042-.14609*1.5+3.87531*lyv-.18677*lyv*lyv
     ;vary(lyv) ; pts=200 ; limits=9,11 ;labels=lyv;start=9.5$
sample;1-52$
partials; effects: ly & ly=9(.1)11$
calc ; b3=b(3) ; b4 = b(4) ; v33=varb(3,3) ; v44 = varb(4,4) ; v34=varb(3,4) $
calc ; lystar = b3/(-2*b4) $
calc ; g3 = -1/(2*b4) ; g4 = b3/(-2)*(-1/b4^2) $
calc ; vlystar=g3^2*v33 + g4^2*v44 + 2*g3*g4*v34 $
calc ; list ; lystar ; sd = sqr(vlystar) $
wald ; labels = 4_bh ; start=b ; var=varb ; fn1=bh3/(-2*bh4)$
Part 4.
import;file="H:\Courses-Stern\Econometrics\Problems\DataFiles\electricity.csv"$
? Set up the data for the regression
create ; logq=log(output) 
       ; logpc=log(cprice) ; logpf=log(fprice) ; logpl=log(lprice)$
create ; logc = log(cost)  ; logq2 = .5*logq*logq $
? Least squares regression
regress;lhs=logc;rhs=one,logq,logq2,logpc,logpf,logpl $
? Explicit computation of the cost function at data means, demonstration.
calc ; meanlpc=log(xbr(cprice))
     ; meanlpf=log(xbr(fprice))
     ; meanlpl=log(xbr(lprice))$
calc ; b1=b(1) ; b2=b(2) ; b3=b(3) ; b4=b(4) ; b5=b(5) ; b6=b(6) $
sample;1$
fplot ; fcn=exp(b1 + (b2-1)*lq + b3*lq*lq*.5 
            + b4*meanlpc+b5*meanlpf+b6*meanlpl )
      ; start =5 ; limits = 2,15 ; pts=200 ;labels = lq 
      ; plot(lq)$
? Compute efficient scale.  Explicitly using theoretical results
calc;list;qstar=exp((1-b2)/b3)$
calc ; g2 = qstar * (-1/b3)
     ; g3 = qstar * (-log(qstar))/b3 $
calc ; v22 = varb(2,2) ; v33 = varb(3,3) ; v23 = varb(2,3) $
calc ; list ; sd = sqr(g2^2*v22 + g3^2*v33 + 2*g2*g3*v23) $ 
calc ; list ; lower = qstar - 1.96*sd
            ; upper = qstar + 1.96*sd $
? The same computation using the built in program function
wald ; start=b
     ; var=varb
     ; labels=6_c
     ; fn1=exp((1-c2)/c3)$

? Part 5.
sample;1-52$
procedure $
regress ; quietly ; lhs = lg ; rhs=one,lpg,ly,ly^2 $
endproc $
exec ; n=50 ; bootstrap=b $
regress ; lhs = lg ; rhs=one,lpg,ly,ly^2 $