? Use only one year of data
?----------------------------------------------------------------------
Reject ; Year # 1988 $
Create ; qi = 2*doctor - 1 $
?----------------------------------------------------------------------
? MLE for the basic probit model
?----------------------------------------------------------------------
Maximize
; Fcn = log(phi(qi *(c0 + c1*female + c2*age + c3*hhninc + c4*educ)))
; Labels = c0,c1,c2,c3,c4
; Start = 0,0,0,0,0 
; Output = 3 $
?----------------------------------------------------------------------
? Verify that that is what the preceding does.
?----------------------------------------------------------------------
Probit ; Lhs = Doctor ; Rhs = one,female,age,hhninc,educ $
?----------------------------------------------------------------------
? Add an unidentified scale parameter to the model. Not identified
?----------------------------------------------------------------------
Maximize
; Fcn = log(phi(qi *((c0 + c1*female + c2*age + c3*hhninc + c4*educ)/theta)))
; Labels = c0,c1,c2,c3,c4,theta
; Start = 0,0,0,0,0,1
; Output=3$

? Is the matrix really singular?
? Compute it and obtain its characteristic roots .
Matrix ; cv=[-.19661/.31811/.013613/-.34992/-.003456] $
Calc   ; th=.99645 $
Names  ; x   =  one,female,age,hhninc,educ$
Create ; ri  =  qi * (cv'x) / th $
Create ; ai  =  n01(ri)/phi(ri) $
Create ; gci =  ai * qi/th $
Create ; gti = -ai * ri/th $
Matrix ; list ; x'gci$
Matrix ; list ; 1'gti$
Create ; di  = -ri*ai - ai*ai $
Create ; hcc =  di / th^2  $ times xx'
Create ; hct =  di * qi/th * (-ri/th) - ai * qi / th^2$ times x
Create ; htt =  di * (-ri/th)^2 +2*ai*ri/th^2 $
dstat;rhs=hcc,hct,htt$
Matrix ; VCC = x'[hcc]x $
Matrix ; Vtc = hct'x $
Matrix ; vtt = 1'htt $
Matrix ; vc = [vcc / vtc,vtt ]$
Matrix ; vc = -vc $
Matrix ; List ; root(vc) $

?----------------------------------------------------------------------
? The same log likelihood function is obtained for every value of theta.
?----------------------------------------------------------------------
Proc = NotID(theta0)
Maximize
; Fcn  = log(phi(qi *((c0 + c1*female + c2*age + c3*hhninc + c4*educ)/theta)))
; Labels = c0,c1,c2,c3,c4,theta
; Start = 0,0,0,0,0,theta0
; Fix=theta $ 
EndProc $
Exec ; Proc=NotID(1) $
Exec ; Proc=NotID(2) $
Exec ; Proc=NotID(3) $
Exec ; Proc=NotID(4) $